Arduino - Sensor de humedad

En esta sección, aprenderemos cómo conectar nuestra placa Arduino con diferentes sensores. Discutiremos los siguientes sensores:

Sensor de humedad (DHT22)
Sensor de temperatura (LM35)
Sensor detector de agua (disparador de agua simple)
SENSOR PIR
SENSOR ULTRASÓNICO
GPS

Sensor de humedad (DHT22)

El DHT-22 (también denominado AM2302) es un sensor de temperatura, humedad relativa y salida digital. Utiliza un sensor de humedad capacitivo y un termistor para medir el aire circundante y envía una señal digital en el pin de datos.

En este ejemplo, aprenderá a utilizar este sensor con Arduino UNO. La temperatura y la humedad de la habitación se imprimirán en el monitor en serie.

El sensor DHT-22

Las conexiones son sencillas. El primer pin de la izquierda a 3-5 V de potencia, el segundo pin al pin de entrada de datos y el pin de la derecha al suelo.

Detalles técnicos

Power - 3-5 V
Max Current - 2,5 mA
Humidity - 0-100%, 2-5% de precisión
Temperature - Precisión de 40 a 80 ° C, ± 0,5 ° C

Componentes requeridos

Necesitará los siguientes componentes:

1 × tablero
1 × Arduino Uno R3
1 × DHT22
1 × resistencia de 10K ohmios

Procedimiento

Siga el diagrama del circuito y conecte los componentes en la placa de pruebas como se muestra en la imagen a continuación.

Bosquejo

Abra el software Arduino IDE en su computadora. La codificación en el lenguaje Arduino controlará su circuito. Abra un nuevo archivo de dibujo haciendo clic en Nuevo.

Código Arduino

// Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2 // what digital pin we're connected to
// Uncomment whatever type you're using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors. This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); // Wait a few seconds between measurements
   float h = dht.readHumidity();
   // Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
   // Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
   // Read temperature as Fahrenheit (isFahrenheit = true)
   // Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   // Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
   // Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

Código a tener en cuenta

El sensor DHT22 tiene cuatro terminales (V _cc , DATA, NC, GND), que se conectan a la placa de la siguiente manera:

Pin de DATOS al pin número 2 de Arduino
Pin V _cc a 5 voltios de placa Arduino
Pin GND al suelo de la placa Arduino
Necesitamos conectar una resistencia de 10k ohmios (resistencia de extracción) entre los DATOS y el pin V _cc

Una vez que se realizan las conexiones de hardware, debe agregar la biblioteca DHT22 a su archivo de biblioteca Arduino como se describió anteriormente.

Resultado

Verá la pantalla de temperatura y humedad en el monitor del puerto serie que se actualiza cada 2 segundos.

↰ Previous page Next page ↱