excel - rango - Iterato sobre la fila de la tabla

funcion buscar h

Question

Estoy estudiando la psicología de Rock Paper Scissors usando Excel. Estoy guardando los juegos en una tabla llamada Juegos con columnas Player0 (qué jugador 0 usó), Player1 y Winner (puede ser 0, 1 o T para Tie).

Quiero saber cuántas victorias se hicieron usando cada opción (1) (tabla a la izquierda), así que necesito iterar sobre cada fila en la tabla para verificar si la ganancia se hizo usando, por ejemplo, rock.

Intenté usar el siguiente COUNTIF para rock

=COUNTIF( Games, IF( IF( $D = 0, $B, IF( $D = 1, $C, FALSE ) ) = "R", TRUE, FALSE ) )

pero no puedo descifrar qué usar para acceder a otras columnas en la misma fila (en lugar de los $ D, $ B, $ C).

El conteo esperado es:

Rock Win - 3
, Paper Win - 0
, Scissor Win - 7
, Tie - 12

(1) Ejemplo: Un Rock Win sería un partido de Rock vs Scissor.

Answer 1

Rock Win:

=COUNTIFS(C:C,"<>T",A:A,"R",B:B,"S")+COUNTIFS(C:C,"<>T",A:A,"S",B:B,"R")

Premio de papel:

=COUNTIFS(C:C,"<>T",A:A,"R",B:B,"P")+COUNTIFS(C:C,"<>T",A:A,"P",B:B,"R")

Triunfo de Tijera:

=COUNTIFS(C:C,"<>T",A:A,"P",B:B,"S")+COUNTIFS(C:C,"<>T",A:A,"S",B:B,"P")

Corbata:

=COUNTIF(C:C,"T")

Answer 2

en I4 use la siguiente

=COUNTIFS(C:C,"R",E:E,"0")+COUNTIFS(D:D,"R",E:E,"1")

Cambie la R a S y luego P en consecuencia para el ppapper o siccor gana

en I7 usa lo siguiente:

=COUNTIF(E:E,"T")

y en I8 use lo siguiente:

=COUNTA(E:E)-1
OR
=SUM(I4:I7)

El -1 es para dar cuenta de las filas del encabezado.

para obtener sus porcentajes utilice lo siguiente en J4 y copie hacia abajo:

=I4/$I$8

Advertencia: todas las celdas debajo de su última entrada deben estar en blanco.

Prueba de concepto

prima

Para determinar los resultados del ganador en la columna E:

=IF(C2=D2,"T",IF(OR(AND(C2="R",D2="S"),AND(C2="P",D2="R"),AND(C2="S",D2="P")),0,1))

ALTERNATIVA

(¡PERO NO PREFERIDO!

Dado que hay varias maneras de hacer las cosas, aquí hay una opción que obtendrá sus recuentos para la columna I al hacer arreglos como cálculos sin ser una matriz:

Para I4 a I6 respectivamente

=SUMPRODUCT(($C$2:$C$23=LEFT($H4))*($D$2:$D$23="s")+($C$2:$C$23="s")*($D$2:$D$23=LEFT($H4)))
=SUMPRODUCT(($C$2:$C$23=LEFT($H5))*($D$2:$D$23="r")+($C$2:$C$23="r")*($D$2:$D$23=LEFT($H5)))
=SUMPRODUCT(($C$2:$C$23=LEFT($H6))*($D$2:$D$23="p")+($C$2:$C$23="p")*($D$2:$D$23=LEFT($H6)))

Para I7, tiene la opción de trabajar con los resultados de su columna E usando:

=SUMPRODUCT(--($E$2:$E$23=LEFT($H7)))

O pasando los resultados de la columna E y usando:

=SUMPRODUCT(--(C2:C23=D2:D23))

Para obtener el total de coincidencias, suma los resultados anteriores o usa

=SUMPRODUCT(--(C2:C23<>""))

Ahora, la razón por la que no se usan las operaciones tipo array es que no se quiere ir con referencias completas de columna, ya que agregaría muchos cálculos adicionales para nada. El beneficio es que puede tener información, es decir, usar las celdas debajo de su mesa sin tener que descartar sus conteos.