crystal-reports - posible - exportar crystal report a pdf c#

¿Cómo hago que PDF sea la opción de exportación predeterminada para Crystal Report?

Question

Estoy trabajando con CrystalDecisions.CrystalReports.Engine.ReportDocument en WinForms en Visual Studio 2008. En este momento, cuando los usuarios hacen clic en el botón exportar, el diálogo predeterminado es guardar el informe como un archivo formateado de CrystalReports. Es posible cambiar el selector a PDF, pero la solicitud específica que se me ha dado (y he buscado demasiadas horas tratando de encontrar) es hacer que el diálogo ''exportar informe'' sea una opción predeterminada en formato PDF.

¿Alguien sabe como hacer esto?

Answer 1

A partir de CR XI, la única forma que conozco es reemplazar el diálogo de exportación con el tuyo. Puede agregar su propio botón al control CrystalReportViewer y ocultar su botón de exportación.

Aquí está el código vb.net para reemplazar el botón de exportación con su propio botón / manipulador de eventos ...

Public Shared Sub SetCustomExportHandler(ByVal crv As CrystalDecisions.Windows.Forms.CrystalReportViewer, ByVal export_click_handler As EventHandler)
        For Each ctrl As Control In crv.Controls
            ''find the toolstrip
            If TypeOf ctrl Is ToolStrip Then
                Dim ts As ToolStrip = DirectCast(ctrl, ToolStrip)

                For Each tsi As ToolStripItem In ts.Items

                    ''find the export button by it''s image index
                    If TypeOf tsi Is ToolStripButton AndAlso tsi.ImageIndex = 8 Then

                        ''CRV export button
                        Dim crXb As ToolStripButton = DirectCast(tsi, ToolStripButton)

                        ''clone the looks of the export button
                        Dim tsb As New ToolStripButton
                        With tsb
                            .Size = crXb.Size
                            .Padding = crXb.Padding
                            .Margin = crXb.Margin
                            .TextImageRelation = crXb.TextImageRelation

                            .Text = crXb.Text
                            .ToolTipText = crXb.ToolTipText
                            .ImageScaling = crXb.ImageScaling
                            .ImageAlign = crXb.ImageAlign
                            .ImageIndex = crXb.ImageIndex
                        End With

                        ''insert custom button in it''s place
                        ts.Items.Insert(0, tsb)

                        AddHandler tsb.Click, export_click_handler

                        Exit For
                    End If
                Next

                Exit For
            End If
        Next

        ''hide the default export button
        crv.ShowExportButton = False
    End Sub

Luego, en el controlador de clics, mostraría un SaveFileDialog personalizado y, finalmente, llamaría al método ReportDocument.ExportToDisk. De esta forma, puede establecer el título y el nombre de archivo del diálogo como algo útil y, por supuesto, establecer el tipo de exportación predeterminado.