erlang - significado - mnesia elixir

Cómo cambiar el nombre del nodo ejecutando una base de datos de mnesia

Question

Creé una base de datos / esquema de Mnesia en machine1. El nodo se denominó mypl @ machine1. Luego moví todos los archivos a machine2, porque la máquina 1 se averió. Todo funciona bien siempre que el código se ejecute con el nombre "mypl @ machine1". Obviamente esto es algo confuso, porque ahora se está ejecutando en machine2.

Si comienzo Erlang con el nombre de nodo "mypl @ machine2", la base de datos Mnesia aparece vacía.

¿Cómo cambio el nombre del nodo en una Base de datos de Mnesia de machine1 a machine2?

Answer 1

La solución alternativa es la migración. Simplemente inicie el clúster de mnesia y migre todas sus tablas y esquemas a otro nodo. Que eliminar del original y se olvidó.

Answer 2

No creo que esto pueda hacerse en línea en un solo nodo (¿alguien?), Pero es posible hacerlo a través de una copia de seguridad / restauración, además de ejecutar dos nodos y agregar copias de tabla. En la guía de usuario de Mnesia, sección 6.9.1, encontrará un código que usa mnesia: traverse_backup para alterar los nombres de los nodos en la tabla de esquema (mostrada a continuación) en un archivo de copia de seguridad de mnesia. El nombre del módulo que probablemente deba usar es mnesia_backup .

Con este código, necesitarás:

%% On mypl@machine1
mnesia:backup("/path/to/mnesia.backup").
change_node_name(mnesia_backup, mypl@machine1, mypl@machine2,
                 "/path/to/mnesia.backup", "/path/to/new.mnesia.backup").
%% On mypl@machine2
mnesia:restore("/path/to/new.mnesia.backup", []).

No estoy seguro si necesita crear el esquema primero en mypl@machine2 .

El código de nombre de nodo de cambio de la guía del usuario:

change_node_name(Mod, From, To, Source, Target) ->
    Switch =
        fun(Node) when Node == From -> To;
           (Node) when Node == To -> throw({error, already_exists});
           (Node) -> Node
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, lists:map(Switch,Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, lists:map(Switch, Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Mod, Target, Mod, Convert, switched).