vba - una - llamar variable de otro modulo excel

¿Cómo declaro una variable global en VBA?

Question

Escribí el siguiente código:

Function find_results_idle()

    Public iRaw As Integer
    Public iColumn As Integer
    iRaw = 1
    iColumn = 1

Y recibo el mensaje de error:

"atributo inválido en Sub o Función"

¿Sabes lo que hice mal?

Traté de usar Global lugar de Public , pero tuve el mismo problema.

Intenté declarar la función en sí misma como `Pública, pero tampoco sirvió de nada.

¿Qué debo hacer para crear la variable global?

Answer 1

Crea un entero público en la Declaración General.

Luego, en su función puede aumentar su valor cada vez. Ver ejemplo (función para guardar adjuntos de un correo electrónico como CSV).

Public Numerator As Integer

Public Sub saveAttachtoDisk(itm As Outlook.MailItem)
Dim objAtt As Outlook.Attachment
Dim saveFolder As String
Dim FileName As String

saveFolder = "c:/temp/"

     For Each objAtt In itm.Attachments
            FileName = objAtt.DisplayName & "_" & Numerator & "_" & Format(Now, "yyyy-mm-dd H-mm-ss") & ".CSV"
                      objAtt.SaveAsFile saveFolder & "/" & FileName
                      Numerator = Numerator + 1

          Set objAtt = Nothing
     Next
End Sub

Answer 2

Esta es una pregunta sobre el scope .

Si solo quiere que las variables duren la vida útil de la función, use Dim (abreviatura de Dimensión ) dentro de la función o sub para declarar las variables:

Function AddSomeNumbers() As Integer
    Dim intA As Integer
    Dim intB As Integer
    intA = 2
    intB = 3
    AddSomeNumbers = intA + intB
End Function
''intA and intB are no longer available since the function ended

Una variable global (como señaló SLaks) se declara fuera de la función utilizando la palabra clave Public . Esta variable estará disponible durante la vida de su aplicación en ejecución. En el caso de Excel, esto significa que las variables estarán disponibles siempre que ese libro de Excel en particular esté abierto.

Public intA As Integer
Private intB As Integer

Function AddSomeNumbers() As Integer
    intA = 2
    intB = 3
    AddSomeNumbers = intA + intB
End Function
''intA and intB are still both available.  However, because intA is public,  ''
''it can also be referenced from code in other modules. Because intB is private,''
''it will be hidden from other modules.

También puede tener variables que solo son accesibles dentro de un módulo (o clase) en particular al declararlas con la palabra clave Private .

Si está creando una gran aplicación y siente la necesidad de usar variables globales, le recomendaría crear un módulo separado solo para sus variables globales. Esto debería ayudarlo a hacer un seguimiento de ellos en un solo lugar.

Answer 3

La pregunta es realmente sobre el alcance, como dijo el otro tipo.

En resumen, considere este "módulo":

Public Var1 As variant     ''Var1 can be used in all
                           ''modules, class modules and userforms of 
                           ''thisworkbook and will preserve any values
                           ''assigned to it until either the workbook
                           ''is closed or the project is reset.

Dim Var2 As Variant        ''Var2 and Var3 can be used anywhere on the
Private Var3 As Variant    ''''current module and will preserve any values
                           ''''they''re assigned until either the workbook
                           ''''is closed or the project is reset.

Sub MySub()                ''Var4 can only be used within the procedure MySub
    Dim Var4 as Variant    ''''and will only store values until the procedure 
End Sub                    ''''ends.

Sub MyOtherSub()           ''You can even declare another Var4 within a
    Dim Var4 as Variant    ''''different procedure without generating an
End Sub                    ''''error (only possible confusion). 

Puede consultar esta referencia de MSDN para obtener más información sobre declaración de variables y esta otra Pregunta de desbordamiento de pila para obtener más información sobre cómo las variables quedan fuera del alcance.

Otras dos cosas rápidas:

1. Organícese cuando use variables de nivel de libro, para que su código no se vuelva confuso. Preferir funciones (con tipos de datos adecuados) o pasar argumentos ByRef .
2. Si desea que una variable preserve su valor entre llamadas, puede usar la instrucción Estática .

Answer 4

Necesita declarar las variables fuera de la función:

Public iRaw As Integer
Public iColumn As Integer

Function find_results_idle()
    iRaw = 1
    iColumn = 1

Answer 5

Para usar variables globales, inserte un nuevo módulo desde la interfaz de usuario del proyecto VBA y declare las variables usando Global

Global iRaw As Integer
Global iColumn As Integer

Answer 6

Si esta función está en un módulo / clase, puede simplemente escribirlos fuera de la función, por lo que tiene Global Scope . Alcance global significa que se puede acceder a la variable mediante otra función en el mismo módulo / clase (si usa dim como declaración, use public si desea que todas las funciones accedan a las variables en todos los módulos):

Dim iRaw As Integer
Dim iColumn As Integer

Function find_results_idle()
    iRaw = 1
    iColumn = 1
End Function

Function this_can_access_global()
    iRaw = 2
    iColumn = 2
End Function