excel - por - Error en tiempo de ejecución ''1004'': Método ''Rango'' de object''_Global ''falló

error en el metodo cells del objeto global

Question

Tengo un problema con excel, con un formulario que genera un no de referencia. Pero cuando intento generar el no de referencia tiene un mensaje de error que dice:

Error en tiempo de ejecución ''1004'': Método ''Rango'' de object''_Global ''falló

Cuando hago clic en el botón Depurar, muestra el código de la siguiente manera:

Resalta el error en la 4ª línea del código

Sub clearTemplate()
    '' Clear Template Content
    Range(inputTemplateHeader) = NO_ENTRY
    Range(inputTemplateContent) = NO_ENTRY     - (highlighted error)
End Sub

Sub clearRefNo()
    '' Clear cell G2 reference number
    Range(cellRefNo) = NO_ENTRY

    '' Open "Report_ref_no.xls"
    If Not (IsFileOpen) Then Workbooks.Open filename:=ThisWorkbook.Path & "/" & FACCESS

    '' Activate "Report_ref_no.xls"
    Windows(FACCESS).Activate

    '' Access column D
    Range(cellFirstRefNo).Select
    Selection.End(xlDown).Select

    If refNo = Cells(ActiveCell.Row, ActiveCell.Column - 1).Value Then
        '' Log Development Code column
        Cells(ActiveCell.Row, ActiveCell.Column) = NO_ENTRY

        '' Log Issuer column
        Cells(ActiveCell.Row, ActiveCell.Column + 1).Value = NO_ENTRY

        '' Log Date column
        Cells(ActiveCell.Row, ActiveCell.Column + 2).Value = NO_ENTRY
    End If

    '' Save & Close workbook
    ActiveWindow.Close True
End Sub

Hay alguien que me puede ayudar con este problema ? No sé lo que salió mal?

Answer 1

Cuando hace referencia a Rango como ese, se denomina referencia no calificada porque no especifica en qué hoja se encuentra el rango. Las referencias no calificadas son manejadas por el objeto "_Global" que determina a qué objeto se refiere y que depende de dónde está el código.

Si se encuentra en un módulo estándar, el Rango no calificado se referirá a la Hoja activa. Si se encuentra en el módulo de clase de una hoja, el Rango no calificado se referirá a esa hoja.

inputTemplateContent es una variable que contiene una referencia a un rango, probablemente un rango con nombre. Si observa la propiedad RefersTo de ese rango con nombre, probablemente apunte a una hoja que no sea la Activesheet en el momento en que se ejecuta el código.

La mejor manera de solucionar esto es evitar referencias de Rango no calificadas al especificar la hoja. Me gusta

With ThisWorkbook.Worksheets("Template")
    .Range(inputTemplateHeader).Value = NO_ENTRY
    .Range(inputTemplateContent).Value = NO_ENTRY
End With

Ajuste el libro de trabajo y las referencias de la hoja de trabajo para adaptarse a su situación particular.