vbscript - ver - ¿Cómo obtengo la ruta al archivo actualmente seleccionado?

obtener la ruta de un archivo en c#

Question

¿Tiene VBScript una función para obtener la ruta al archivo actualmente seleccionado en el Explorador de archivos? Si es así, ¿cuál es la función? Estoy buscando algo así como

Set fileObj = CreateObject("Scripting.FileSystemObject")
dim filepath
filepath = fileObj.GetCurrentSelection() ''doesn´t exist
dim result
result = filepath ''communicate with LiveCode

Answer 1

Escribí un simple ejemplo.
Tenga en cuenta que puede haber más de una ventana abierta de explorador de Windows y esto los listará a todos.

Function GetSelectedFiles() ''Returns paths as array of strings
Dim FileList, Window, SelectedItem
''avoid duplicates by storing paths in dictionary keys
Set FileList = CreateObject("Scripting.Dictionary")
With CreateObject("Shell.Application")
For Each Window In .Windows
''skip IE Windows
If InStr(1, Window.FullName, "iexplore.exe", vbTextCompare) = 0 Then
For Each SelectedItem In Window.Document.SelectedItems
FileList(SelectedItem.Path) = Null
Next
End If
Next
End With
GetSelectedFiles = FileList.Keys ''array of paths
End Function
MsgBox "Click OK after selecting the items", _
vbOKOnly Or vbInformation, "Select a few items"
Dim SelectedFiles
SelectedFiles = GetSelectedFiles
MsgBox "You selected: " & vbNewLine & vbNewLine & _
Join(SelectedFiles, vbNewLine), vbOKOnly Or vbInformation, "Selected Items"
''loop through array
''Dim FileItem
''For Each FileItem In SelectedFiles
'' WScript.Echo FileItem
''Next

Answer 2

intente esto, puede obtener la ruta al archivo seleccionado actualmente. También necesita

Set objFS=CreateObject("Scripting.FileSystemObject")
Set objArgs = WScript.Arguments
strFile= objArgs(0)
Set objFile = objFS.OpenTextFile(strFile)
Set objFile = objFS.GetFile(strFile)
WScript.Echo objFile.Path